VLOOKUP Function sa Excel – Giya sa Nagsugod: Syntax ug Mga Ehemplo

Karon nagsugod kami sa usa ka serye sa mga artikulo nga naghulagway sa usa sa labing mapuslanon nga bahin sa Excel − VPR (VLOOKUP). Kini nga function, sa samang higayon, usa sa labing komplikado ug dili kaayo masabtan.

Sa kini nga tutorial sa VPR Paningkamutan nako nga ibutang ang mga sukaranan sa yano kutob sa mahimo aron mahimo ang proseso sa pagkat-on nga tin-aw kutob sa mahimo alang sa mga walay kasinatian nga tiggamit. Dugang pa, tun-an namon ang daghang mga pananglitan nga adunay mga pormula sa Excel nga magpakita sa labing kasagaran nga mga kaso sa paggamit alang sa function VPR.

  • Kinatibuk-ang paghulagway ug syntax
  • Mga Ehemplo sa VLOOKUP
    • Giunsa paggamit ang VLOOKUP sa pagpangita sa lain nga sheet sa Excel
    • Pangitaa sa laing workbook gamit ang VLOOKUP
    • Giunsa paggamit ang usa ka ginganlan nga range o lamesa sa mga pormula nga adunay VLOOKUP
    • Paggamit sa mga Wildcard sa mga Pormula sa VLOOKUP
  • Eksakto o gibanabana nga tugma sa VLOOKUP function
  • VLOOKUP sa Excel – kinahanglan nimong hinumdoman kini!

VLOOKUP function sa Excel – kinatibuk-ang paghulagway ug syntax

So unsa na VPR? Aw, una sa tanan, kini usa ka function sa Excel. Unsay iyang gibuhat? Gipangita niini ang bili nga imong gipiho ug gibalik ang katugbang nga bili gikan sa laing kolum. Sa teknikal nga paagi, VPR pangitaa ang bili sa unang kolum sa gihatag nga han-ay ug ibalik ang resulta gikan sa laing kolum sa samang laray.

Sa labing komon nga aplikasyon, ang function VPR nangita sa database alang sa gihatag nga talagsaon nga identifier ug nagkuha sa pipila ka impormasyon nga may kalabutan niini gikan sa database.

Unang letra sa ngalan sa function VPR (VLOOKUP) nagpasabot Вbertikal (Vbertikal). Pinaagi niini ikaw makaila VPR gikan sa GPR (HLOOKUP), nga nangita og bili sa ibabaw nga laray sa usa ka range − Гpinahigda (Hhorizontally).

function VPR anaa sa Excel 2013, Excel 2010, Excel 2007, Excel 2003, Excel XP, ug Excel 2000.

Syntax sa VLOOKUP function

function VPR (VLOOKUP) adunay mosunod nga syntax:

VLOOKUP(lookup_value,table_array,col_index_num,[range_lookup])

ВПР(искомое_значение;таблица;номер_столбца;[интервальный_просмотр])

Sama sa imong makita, usa ka function VPR sa Microsoft Excel adunay 4 nga mga kapilian (o mga argumento). Ang una nga tulo mao ang mandatory, ang katapusan mao ang opsyonal.

  • lookup_value (lookup_value) – Ang bili nga pangitaon. Kini mahimo nga usa ka bili (numero, petsa, teksto) o usa ka cell reference (naglangkob sa lookup value), o usa ka bili nga gibalik sa uban nga Excel function. Pananglitan, kini nga pormula mangita alang sa kantidad 40:

    =VLOOKUP(40,A2:B15,2)

    =ВПР(40;A2:B15;2)

Kung ang bili sa pagpangita ubos pa sa pinakagamay nga bili sa unang kolum sa han-ay nga gitan-aw, ang function VPR magreport ug sayop #AT (#N/A).

  • lamesa_array (talaan) – duha o labaw pa nga mga kolum sa datos. Hinumdomi, ang function VPR kanunay mangita sa bili sa unang kolum sa han-ay nga gihatag sa argumento lamesa_array (lamesa). Ang matan-aw nga han-ay mahimong adunay lainlaing mga datos, sama sa teksto, petsa, numero, boolean. Ang function kay case insensitive, nagpasabot nga ang upper ug lower case nga mga karakter gikonsiderar nga pareho. Busa ang among pormula mangita sa bili 40 sa mga selula gikan sa A2 sa A15, tungod kay ang A mao ang unang kolum sa han-ay A2:B15 nga gihatag sa argumento lamesa_array (lamesa):

    =VLOOKUP(40,A2:B15,2)

    =ВПР(40;A2:B15;2)

  • col_index_num (column_number) mao ang gidaghanon sa column sa gihatag nga range diin ang bili sa nakit-an nga laray ibalik. Ang pinakawala nga kolum sa gihatag nga range mao ang 1, ang ikaduhang kolum mao ang 2, ang ikatulo nga kolum mao ang 3 ug uban pa. Karon mahimo nimong basahon ang tibuok nga pormula:

    =VLOOKUP(40,A2:B15,2)

    =ВПР(40;A2:B15;2)

    Pormula nga nangitag bili 40 sa range A2:A15 ug ibalik ang katumbas nga kantidad gikan sa kolum B (tungod kay ang B mao ang ikaduhang kolum sa range A2:B15).

Kung ang bili sa argumento col_index_num (column_number) ubos pa kay sa 1unya VPR magreport ug sayop #BILI! (#BILI!). Ug kung kini labaw pa sa gidaghanon sa mga kolum sa range lamesa_array (lamesa), ang function magbalik sa usa ka sayup #REF! (#LINK!).

  • range_lookup (range_lookup) – nagtino kon unsay pangitaon:
    • eksakto nga pagkapareha, ang argumento kinahanglan nga managsama SAYOP (SAYOK);
    • gibanabana nga tugma, argumento managsama TINUOD NGA KODE (TINUOD) o wala gitino sa tanan.

    Opsyonal kini nga parameter, apan hinungdanon kaayo. Sa ulahi niini nga tutorial sa VPR Ipakita ko kanimo ang pipila ka mga pananglitan nga nagpatin-aw kung giunsa pagsulat ang mga pormula alang sa pagpangita sa eksakto ug gibanabana nga mga tugma.

Mga Ehemplo sa VLOOKUP

Manghinaut ko nga ang function VPR mahimong mas klaro kanimo. Karon atong tan-awon ang pipila ka mga kaso sa paggamit VPR sa mga pormula nga adunay tinuod nga datos.

Giunsa paggamit ang VLOOKUP sa pagpangita sa lain nga sheet sa Excel

Sa praktis, mga pormula nga adunay function VPR panagsa ra nga gigamit sa pagpangita sa datos sa parehas nga worksheet. Mas kasagaran kay sa dili, mangita ka ug makuha ang katugbang nga mga kantidad gikan sa laing sheet.

Aron sa paggamit sa VPR, pangitaa sa laing Microsoft Excel sheet, Kinahanglan nimo sa argumento lamesa_array (talaan) ipiho ang ngalan sa sheet nga adunay marka sa pagtuaw nga gisundan sa lainlaing mga cell. Pananglitan, ang mosunod nga pormula nagpakita nga ang range A2: B15 naa sa sheet nga ginganlag Palid 2.

=VLOOKUP(40,Sheet2!A2:B15,2)

=ВПР(40;Sheet2!A2:B15;2)

Siyempre, ang ngalan sa sheet dili kinahanglan nga isulod sa mano-mano. Pagsugod lang sa pag-type sa pormula, ug kung bahin sa argumento lamesa_array (lamesa), balhin sa gusto nga sheet ug pilia ang gusto nga range sa mga cell gamit ang mouse.

Ang pormula nga gipakita sa screenshot sa ubos nangita sa teksto nga "Produkto 1" sa column A (kini ang 1st column sa range A2:B9) sa worksheet presyo sa.

=VLOOKUP("Product 1",Prices!$A$2:$B$9,2,FALSE)

=ВПР("Product 1";Prices!$A$2:$B$9;2;ЛОЖЬ)

Palihug hinumdumi nga sa pagpangita sa usa ka kantidad sa teksto, kinahanglan nimo nga ilakip kini sa mga marka sa kinutlo (""), sama sa kasagaran nga gihimo sa mga pormula sa Excel.

Alang sa argumento lamesa_array (lamesa) tilinguhaon nga gamiton kanunay ang hingpit nga mga pakisayran (uban ang $ sign). Niini nga kaso, ang hanay sa pagpangita magpabilin nga wala mausab kung kopyahon ang pormula sa ubang mga cell.

Pangitaa sa laing workbook gamit ang VLOOKUP

Aron molihok VPR nagtrabaho tali sa duha ka mga workbook sa Excel, kinahanglan nimong ipiho ang ngalan sa workbook sa square bracket sa wala pa ang ngalan sa sheet.

Pananglitan, sa ubos usa ka pormula nga nangita alang sa kantidad 40 sa palid Palid 2 sa libro Numero.xlsx:

=VLOOKUP(40,[Numbers.xlsx]Sheet2!A2:B15,2)

=ВПР(40;[Numbers.xlsx]Sheet2!A2:B15;2)

Ania ang labing kadali nga paagi aron makahimo usa ka pormula sa Excel nga adunay VPRnga nagsumpay sa laing workbook:

  1. Ablihi ang duha ka libro. Dili kini gikinahanglan, apan mas sayon ​​ang paghimo og pormula niining paagiha. Dili nimo gusto nga mano-mano nga mosulod sa ngalan sa workbook, dili ba? Dugang pa, kini manalipod kanimo gikan sa aksidenteng typos.
  2. Pagsugod sa pag-type sa usa ka function VPRug sa diha nga kini moabut ngadto sa argumento lamesa_array (lamesa), balhin sa laing workbook ug pilia ang gikinahanglan nga hanay sa pagpangita niini.

Ang screenshot sa ubos nagpakita sa pormula nga adunay search set sa usa ka range sa workbook PriceList.xlsx sa palid presyo sa.

function VPR molihok bisan kung imong gisirhan ang gipangita nga workbook ug ang tibuuk nga agianan sa file sa workbook makita sa formula bar, ingon sa gipakita sa ubos:

Kung ang ngalan sa workbook o sheet adunay mga espasyo, nan kini kinahanglan nga gilakip sa mga apostrophe:

=VLOOKUP(40,'[Numbers.xlsx]Sheet2'!A2:B15,2)

=ВПР(40;'[Numbers.xlsx]Sheet2'!A2:B15;2)

Giunsa paggamit ang usa ka ginganlan nga range o lamesa sa mga pormula nga adunay VLOOKUP

Kung nagplano ka nga gamiton ang parehas nga hanay sa pagpangita sa daghang mga gimbuhaton VPR, makahimo ka og usa ka ginganlan nga range ug isulod ang ngalan niini ngadto sa pormula isip argumento lamesa_array (lamesa).

Aron makamugna og gihinganlan nga range, pilia lang ang mga cell ug isulod ang angay nga ngalan sa field unang ngalan, sa wala sa formula bar.

Karon mahimo nimong isulat ang mosunod nga pormula sa pagpangita sa presyo sa usa ka produkto Product 1:

=VLOOKUP("Product 1",Products,2)

=ВПР("Product 1";Products;2)

Kadaghanan sa mga ngalan sa hanay nagtrabaho alang sa tibuuk nga workbook sa Excel, busa dili kinahanglan nga ipiho ang ngalan sa sheet alang sa argumento lamesa_array (lamesa), bisan kung ang pormula ug ang hanay sa pagpangita naa sa lainlaing mga worksheet. Kung naa sila sa lainlaing mga workbook, unya sa wala pa ang ngalan sa range kinahanglan nimo nga ipiho ang ngalan sa workbook, pananglitan, sama niini:

=VLOOKUP("Product 1",PriceList.xlsx!Products,2)

=ВПР("Product 1";PriceList.xlsx!Products;2)

Busa ang pormula tan-awon nga mas klaro, mouyon? Usab, ang paggamit sa ginganlan nga mga han-ay usa ka maayong alternatibo sa hingpit nga mga pakisayran tungod kay ang ginganlan nga han-ay dili mausab kung imong kopyahon ang pormula ngadto sa ubang mga selula. Kini nagpasabut nga makasiguro ka nga ang hanay sa pagpangita sa pormula kanunay nga magpabilin nga husto.

Kung imong i-convert ang usa ka range sa mga cell ngadto sa usa ka hingpit nga Excel spreadsheet gamit ang command Table (Talaan) tab pagsal-ot (Isuksok), unya kon mopili ka ug range gamit ang mouse, ang Microsoft Excel awtomatikong idugang ang mga ngalan sa kolum (o ang ngalan sa lamesa kon imong pilion ang tibuok lamesa) sa pormula.

Ang nahuman nga pormula motan-aw sama niini:

=VLOOKUP("Product 1",Table46[[Product]:[Price]],2)

=ВПР("Product 1";Table46[[Product]:[Price]];2)

O tingali ingon niini:

=VLOOKUP("Product 1",Table46,2)

=ВПР("Product 1";Table46;2)

Kung gigamit ang mga gihinganlan nga range, ang mga link magpunting sa parehas nga mga cell bisan asa nimo kopyahon ang function VPR sulod sa workbook.

Paggamit sa mga Wildcard sa mga Pormula sa VLOOKUP

Sama sa daghang uban pang mga gimbuhaton, VPR Mahimo nimong gamiton ang mosunod nga mga karakter sa wildcard:

  • Pangutana nga marka (?) – mopuli sa bisan unsa nga karakter.
  • Asterisk (*) – nag-ilis sa bisan unsang han-ay sa mga karakter.

Paggamit sa mga Wildcard sa mga Function VPR mahimong mapuslanon sa daghang mga kaso, pananglitan:

  • Kung dili nimo mahinumduman ang eksakto nga teksto nga kinahanglan nimo pangitaon.
  • Kung gusto nimo mangita usa ka pulong nga bahin sa sulud sa usa ka cell. Hibaloi kana VPR nangita pinaagi sa mga sulod sa cell sa kinatibuk-an, ingon nga ang opsyon gipalihok Ipares ang tibuok sulod sa cell (Tibuok cell) sa standard nga pagpangita sa Excel.
  • Kung ang usa ka cell adunay dugang nga mga espasyo sa sinugdanan o katapusan sa sulud. Sa ingon nga sitwasyon, mahimo nimong i-rack ang imong utok sa dugay nga panahon, pagsulay nga mahibal-an kung ngano nga ang pormula dili molihok.

Pananglitan 1: Pagpangita sa teksto nga nagsugod o natapos sa pipila ka mga karakter

Ingnon ta nga gusto nimo pangitaon ang usa ka piho nga kustomer sa database nga gipakita sa ubos. Dili nimo mahinumduman ang iyang apelyido, apan nahibal-an nimo nga kini nagsugod sa "ack". Ania ang usa ka pormula nga mahimo’g maayo ang trabaho:

=VLOOKUP("ack*",$A$2:$C$11,1,FALSE)

=ВПР("ack*";$A$2:$C$11;1;ЛОЖЬ)

Karon nga sigurado ka nga nakit-an nimo ang husto nga ngalan, mahimo nimong gamiton ang parehas nga pormula aron makit-an ang kantidad nga gibayad sa kini nga kustomer. Aron mahimo kini, usba lang ang ikatulo nga argumento sa function VPR sa gusto nga numero sa kolum. Sa among kaso, kini ang kolum C (ika-3 sa range):

=VLOOKUP("ack*",$A$2:$C$11,3,FALSE)

=ВПР("ack*";$A$2:$C$11;3;ЛОЖЬ)

Ania ang pipila pa nga mga pananglitan nga adunay mga wildcard:

~ Pangitag ngalan nga nagtapos sa “lalaki”:

=VLOOKUP("*man",$A$2:$C$11,1,FALSE)

=ВПР("*man";$A$2:$C$11;1;ЛОЖЬ)

~ Pangitag ngalan nga nagsugod sa “ad” ug natapos sa “anak”:

=VLOOKUP("ad*son",$A$2:$C$11,1,FALSE)

=ВПР("ad*son";$A$2:$C$11;1;ЛОЖЬ)

~ Atong makita ang unang ngalan sa listahan, nga naglangkob sa 5 ka karakter:

=VLOOKUP("?????",$A$2:$C$11,1,FALSE)

=ВПР("?????";$A$2:$C$11;1;ЛОЖЬ)

Aron molihok VPR uban sa mga wildcard nagtrabaho sa husto, ingon nga ang ikaupat nga argumento kinahanglan nimo kanunay gamiton SAYOP (BAKAK). Kung ang hanay sa pagpangita adunay labaw sa usa ka kantidad nga motakdo sa mga termino sa pagpangita sa mga wildcard, nan ang una nga nakit-an nga kantidad ibalik.

Pananglitan 2: Paghiusa sa mga wildcard ug mga reference sa cell sa mga pormula sa VLOOKUP

Karon atong tan-awon ang usa ka gamay nga mas komplikado nga pananglitan kung unsaon pagpangita gamit ang function VPR pinaagi sa bili sa usa ka cell. Hunahunaa nga ang kolum A usa ka lista sa mga yawe sa lisensya, ug ang kolum B usa ka lista sa mga ngalan nga adunay lisensya. Dugang pa, ikaw adunay bahin (daghang mga karakter) sa usa ka matang sa yawe sa lisensya sa cell C1, ug gusto nimo pangitaon ang ngalan sa tag-iya.

Mahimo kini gamit ang mosunod nga pormula:

=VLOOKUP("*"&C1&"*",$A$2:$B$12,2,FALSE)

=ВПР("*"&C1&"*";$A$2:$B$12;2;FALSE)

Kini nga pormula nagtan-aw sa bili gikan sa cell C1 sa gihatag nga han-ay ug mibalik sa katumbas nga bili gikan sa column B. Timan-i nga sa unang argumento, migamit kami ug ampersand (&) nga karakter sa wala pa ug human sa cell reference aron masumpay ang text string.

Sama sa imong makita sa numero sa ubos, ang function VPR mibalik sa "Jeremy Hill" tungod kay ang iyang yawe sa lisensya naglangkob sa han-ay sa mga karakter gikan sa cell C1.

Matikdi nga ang argumento lamesa_array (lamesa) sa screenshot sa ibabaw naglangkob sa ngalan sa lamesa (Table7) imbes nga ipiho ang usa ka range sa mga cell. Mao kini ang atong gibuhat sa miaging pananglitan.

Eksakto o gibanabana nga tugma sa VLOOKUP function

Ug sa katapusan, atong tan-awon pag-ayo ang katapusang argumento nga gipiho alang sa function VPR - range_lookup (interval_view). Sama sa gihisgutan sa sinugdanan sa leksyon, kini nga argumento importante kaayo. Mahimo nimong makuha ang hingpit nga lainlaing mga resulta sa parehas nga pormula nga adunay kantidad niini TINUOD NGA KODE (Tinuod) o SAYOP (BAKAK).

Una, atong hibal-an kung unsa ang gipasabut sa Microsoft Excel sa eksakto ug gibanabana nga mga tugma.

  • Kung ang argumento range_lookup (range_lookup) katumbas sa SAYOP (FALSE), ang pormula nangita alang sa usa ka eksakto nga tugma, ie parehas nga kantidad nga gihatag sa argumento lookup_value (lookup_value). Kon sa unang kolum sa han-ay tmakahimo_array (lamesa) makasugat og duha o labaw pa nga mga kantidad nga mohaum sa argumento lookup_value (search_value), unya ang una maoy pilion. Kung wala’y nakit-an nga mga tugma, ang function magreport usa ka sayup #AT (#N/A). Pananglitan, ang mosunod nga pormula magreport sa usa ka sayup #AT (#N/A) kung walay bili sa range A2:A15 4:

    =VLOOKUP(4,A2:B15,2,FALSE)

    =ВПР(4;A2:B15;2;ЛОЖЬ)

  • Kung ang argumento range_lookup (range_lookup) katumbas sa TINUOD NGA KODE (TRUE), ang pormula nangita alang sa usa ka gibanabana nga tugma. Mas tukma, una ang function VPR mangita ug eksaktong tugma, ug kung walay makit-an, pilion ang gibanabana. Ang gibanabana nga tugma mao ang pinakadako nga kantidad nga dili molapas sa kantidad nga gipiho sa argumento. lookup_value (lookup_value).

Kung ang argumento range_lookup (range_lookup) katumbas sa TINUOD NGA KODE (TRUE) o wala gipiho, nan ang mga kantidad sa una nga kolum sa han-ay kinahanglan nga ihan-ay sa pataas nga han-ay, nga mao, gikan sa labing gamay hangtod sa pinakadako. Kung dili, ang function VPR mahimong makabalik og sayop nga resulta.

Aron mas masabtan ang kamahinungdanon sa pagpili TINUOD NGA KODE (KAMATUORAN) o SAYOP (FALSE), atong tan-awon ang uban pang mga pormula nga adunay function VPR ug tan-awa ang mga resulta.

Pananglitan 1: Pagpangita usa ka Eksaktong Tugma sa VLOOKUP

Sama sa imong nahinumduman, sa pagpangita alang sa usa ka eksaktong tugma, ang ikaupat nga argumento sa function VPR dapat importante SAYOP (BAKAK).

Balikan nato ang lamesa gikan sa una nga pananglitan ug hibal-an kung unsang hayop ang makalihok sa tulin 50 milya kada oras. Nagtuo ko nga kini nga pormula dili makahatag kanimo og bisan unsang mga kalisdanan:

=VLOOKUP(50,$A$2:$B$15,2,FALSE)

=ВПР(50;$A$2:$B$15;2;ЛОЖЬ)

Timan-i nga ang among hanay sa pagpangita (kolum A) adunay duha ka kantidad 50 - sa mga selula A5 и A6. Ang pormula nagbalik sa bili gikan sa cell B5. Ngano man? Tungod kay kung nangita alang sa usa ka eksaktong tugma, ang function VPR naggamit sa unang bili nga nakit-an nga mohaum sa usa nga gipangita.

Panig-ingnan 2: Paggamit sa VLOOKUP aron Makapangita og Gibanabana nga Tugma

Kung gigamit nimo ang function VPR sa pagpangita alang sa usa ka gibanabana nga tugma, ie sa diha nga ang argumento range_lookup (range_lookup) katumbas sa TINUOD NGA KODE (TRUE) o wala, ang unang butang nga kinahanglan nimong buhaton mao ang paghan-ay sa han-ay pinaagi sa unang kolum sa pataas nga han-ay.

Kini mao ang importante kaayo tungod kay ang function VPR ibalik ang sunod nga pinakadako nga kantidad pagkahuman sa gihatag, ug dayon ang pagpangita mohunong. Kung gipasagdan nimo ang husto nga paghan-ay, adunay ka katingad-an nga mga sangputanan o usa ka mensahe sa sayup. #AT (#N/A).

Karon mahimo nimong gamiton ang usa sa mosunod nga mga pormula:

=VLOOKUP(69,$A$2:$B$15,2,TRUE) or =VLOOKUP(69,$A$2:$B$15,2)

=ВПР(69;$A$2:$B$15;2;ИСТИНА) or =ВПР(69;$A$2:$B$15;2)

Sama sa imong nakita, gusto nakong mahibal-an kung kinsa sa mga hayop ang adunay labing duol nga tulin 69 milya kada oras. Ug ania ang resulta ang function mibalik kanako VPR:

Sama sa imong nakita, ang pormula nagbalik usa ka resulta Antelope (Antelope), kansang katulin 61 milya kada oras, bisan pa ang listahan naglakip usab cheetah (Cheetah) nga kusog kaayong midagan 70 milya kada oras, ug ang 70 mas duol sa 69 kaysa 61, dili ba? Nganong nahitabo kini? Kay ang function VPR kung nangita alang sa usa ka gibanabana nga tugma, ibalik ang labing kadaghan nga kantidad nga dili labaw sa usa nga gipangita.

Nanghinaut ko nga kini nga mga pananglitan naghatag kahayag sa pagtrabaho kauban ang function VPR sa Excel, ug dili na nimo siya tan-awon nga gawas. Karon dili na masakit nga balikon sa makadiyot ang yawe nga mga punto sa materyal nga among gitun-an aron mas maayo nga matul-id kini sa memorya.

VLOOKUP sa Excel – kinahanglan nimong hinumdoman kini!

  1. function VPR Ang Excel dili makalingi sa wala. Kanunay kining mangita sa bili sa pinakawala nga kolum sa han-ay nga gihatag sa argumento lamesa_array (lamesa).
  2. Sa paglihok VPR ang tanan nga mga kantidad kay case-insensitive, ie ang gagmay ug dagkong mga letra parehas.
  3. Kung ang kantidad nga imong gipangita mas gamay kaysa sa minimum nga kantidad sa una nga kolum sa range nga gitan-aw, ang function VPR magreport ug sayop #AT (#N/A).
  4. Kung ika-3 nga argumento col_index_num (column_number) ubos pa kay sa 1function VPR magreport ug sayop #BILI! (#BILI!). Kung mas dako pa sa gidaghanon sa mga column sa range lamesa_array (lamesa), ang function magreport sa usa ka sayup #REF! (#LINK!).
  5. Gamita ang absolute cell references sa argumento lamesa_array (lamesa) aron ang husto nga hanay sa pagpangita mapreserbar kung kopyahon ang pormula. Sulayi ang paggamit sa ginganlan nga mga han-ay o mga lamesa sa Excel isip alternatibo.
  6. Kung maghimo usa ka gibanabana nga pagpangita sa posporo, hinumdomi nga ang una nga kolum sa han-ay nga imong gipangita kinahanglan ihan-ay sa pataas nga han-ay.
  7. Sa kataposan, hinumdomi ang kamahinungdanon sa ikaupat nga argumento. Gamita ang mga mithi TINUOD NGA KODE (KAMATUORAN) o SAYOP (FALSE) tinuyo ug mawagtang nimo ang daghang labad sa ulo.

Sa mosunod nga mga artikulo sa among function tutorial VPR sa Excel, makakat-on kita og mas abante nga mga pananglitan, sama sa paghimo sa lain-laing mga kalkulasyon gamit VPR, pagkuha sa mga kantidad gikan sa daghang mga kolum, ug daghan pa. Salamat sa pagbasa niini nga tutorial ug nanghinaut ko nga magkita ta pag-usab sunod semana!

Leave sa usa ka Reply